Blog.Grails.Kr

이 글은 [1]의 9장 RestController를 보고 작성한 것입니다. RestController를 상속받는 것만으로 도메인 객체를 Web Service로 노출 시킬 수 있습니다. [1]의 소스는 scaffold의 관례를 그대로 따르도록 돼 있습니다. 여기서는 몇 가지 기능을 수정 하고 정리한 것입니다.

• 'id'말고 다른 프로퍼티를 key로 사용할 수 있도록 수정 - 도메인 객체별로 다른 프로퍼티를 key로 사용할 수 있도록 수정했습니다.

먼저 UrlMappings 파일에서 다음과 같이 설정합니다.:

class UrlMappings {
    static mappings = {
    	"/book/$restKey?"(controller:"book"){
    		action = [GET:"show", PUT:"create", POST:"update", DELETE:"delete"]
    	}
    	//이 라인이 있어야 /book/sample에 매핑됩니다. 순서가 restful action(/book/$restKey)보다 먼저 나오면 안됩니다.
    	"/book/$action"(controller:"book")
	}
}

그리고 해당 도메인 객체에서 static restKeyProperty에 key로 사용할 프로퍼티 명을 적어줍니다.

package kr.grails
 
class Book {
	String name
 
	//final은 값을 변경해버리는 실수를 방지하기 위해서 넣은 것입니다. 
	static final restKey="name"
}

원래 /$domain/$id로만 가능했던 것을 Book의 경우에는 /book/$name로도 접근할 수 있도록 수정하였습니다.

• 결과를 반환하는 것을 Content negotiation이 동작하도록 수정하였습니다.

[1]의 코드의 경우 UrlMappings와 RestController.format()은 다음과 같이 구현 돼 있습니다.

        "/$rest/$domain/$id?"{
            controller = "rest"
            action = [GET:"show", PUT:"create", POST:"update", DELETE:"delete"]
            constraints {
                rest(inList:["rest","json"])
            }
        }

	private format(obj) {
		def restType = (params.rest == "rest")?"XML":"JSON"
		render obj."encodeAs$restType"()
	}

즉 uri에 명시한 포멧에 따라서 결과의 포멧이 결정됩니다. 이 것이 바람직 하지 않아보여서 코드를 수정했습니다.

	protected format(obj) {
		withFormat{
			form { render obj as JSON }
			json { render obj as JSON }
			html { render (contentType:"text/plain",text: obj as JSON) }
		}
	}

요청의 Content Type에 따라 반환하는 결과의 형식이 달라집니다. 'text/html', 'text/json', 'text/plain'으로 요청하면 JSON으로 반환합니다. XML보다 JSON이 여러모로 편리하기에 XML은 빼버렸습니다. XML도 추가하면 쉽게 추가됩니다. 원래는 XML도 가능하게 했었는데 테스트 만들기 귀찮아서 빼버렸습니다.-_-;;;이 경우에 XML보다 JSON이 유용해 보여요.

아 'text/josn'을 json으로 알게해주기 위해 config.groovy파일도 수정합니다.

grails.mime.types = [ ...
                      json: ['text/json'],
                      ...
                    ]

• scaffold를 사용하듯이 도메인 클래스를 알려줄 수 있도록 했습니다.

package kr.grails
 
class BookController extends RestController{
	//grails의 scaffold 모델과 최대한 비슷하게 만들려고 노력했습니다.
	def restScaffold = Book
 
	//이것은 UrlMappings의 샘플을 위해 만든 것입니다.
	def sample = {
		render "sample"
	}
}

물론 UrlsMappings.groovy에서 '$domain'으로 도메인 클래스을 노출시키는 것은 삭제했습니다. filter 설저등 uri 기반으로 사용하는데 불편하고 제약 사항도 좀 있었습니다.

소스 코드를 올립니다. [1]의 코드보다 좀 더 유연하게 수정했습니다. 이제 grails의 scaffold를 이용해서 어플리케이션을 쉽게 만들 었던 것처럼 restScaffold를 정의함으로써 쉽게 웹 서비스를 만들 수 있습니다.(물론 개선 사항이 많을 것이라고 생각합니다…)

restful_web_service.tar.gz

/src/groovy에 위치시킵니다. 이 코드를 controllers 폴더에 넣으면 grails의 DI로 인해 코드가 꼬여버리는 것 같습니다. 일단은 컨트롤러를 상속시켜 버렸으니까요. RestController라는 특별한 Controller에 대한 논쟁도 있었나 봅니다만,,,기각된 것 같습니다.

package kr.grails
 
import static org.apache.commons.lang.StringUtils.*
import org.codehaus.groovy.runtime.InvokerHelper
import org.codehaus.groovy.grails.commons.GrailsDomainClass
import grails.converters.*
import static javax.servlet.http.HttpServletResponse.*
 
//abstract로 선언하는 것이 적합해 보였지만 테스트를 위해서 선언하지 않았습니다.
class RestController {
	protected def restKeyProperty = "id"
 
	def show = {
		def result
		if(params.restKey) {
			result = invoke("read", params.restKey)
		} else {
			if(!params.max) params.max = 10
			result = invoke("list", params)
		}
 
		if(result == null) {
			response.sendError(SC_NOT_FOUND, "${restScaffold.class.name} not found with ${this.restKeyProperty}[${params.restKey}]")
		}else{
			format(result)
		}
	}
 
	// updates a domain object
	def update = {
		def domain = invoke("get", params.restKey)
 
		if(domain == null) {
			response.sendError(SC_NOT_FOUND, "${restScaffold.class.name} not found with ${this.restKeyProperty}[${params.restKey}]")
			return
		}
		mapParams()
 
		domain.properties = params
 
		if(!domain.hasErrors() && domain.save()) {
			format(domain)
		} else {
			response.sendError(SC_BAD_REQUEST, "${restScaffold.class.name} could not be saved with ${this.restKeyProperty}[${params.restKey}]")
		}
	}
 
	protected mapParams() {
		withFormat{
			form{
				def input = ""
				request.inputStream.eachLine {
					input += it
				}
 
				// convert input to name/value pairs
				if(input  && input != '') {
					input.tokenize('&').each{
						def nvp = it.tokenize('=');
						params.put(nvp[0],nvp[1]);
					}
				}
			}
			json{
				request.JSON.each{ key, value -> params.put(key, value) }
			}
		}
	}
 
	// create a domain object
	def create = {
		def result
		def domain = InvokerHelper.invokeConstructorOf(restScaffold, null)
 
		mapParams()
		domain.properties = params
 
		if(!domain.hasErrors() && domain.save()) {
			result = domain
		}
		else {
			log.error domain.errors
			result = response.sendError(SC_BAD_REQUEST, "${restScaffold.class.name} could not be created with ${this.restKeyProperty} of ${params.$restKey}")
		}
 
		format(result)
	}
 
	// deletes a domain object
	def delete = {
		def result = invoke("get", params.restKey);
 
		if(result) {
			result.delete()
			format(result)
		} else {
			result = response.sendError(SC_NOT_FOUND, "${restScaffold.class.name} not found with ${this.restKeyProperty}[${params.$restKey}]")
		}
	}
 
	def beforeInterceptor = {
		//detect domain class
		if( !this.metaClass.hasProperty(this, "restScaffold") ) {
			response.sendError(SC_NOT_FOUND, "not found domain class")
			return false
		}
 
		//detect rest key property
		if( restScaffold.metaClass.hasProperty(restScaffold, "restKey") ) {
			this.restKeyProperty = restScaffold.restKey
		}
		true
	}
 
	protected invoke(method, parameters) {
		if( ( method == "read" || method == "get") && this.restKeyProperty != "id") {
			def capitalized = capitalize( this.restKeyProperty )
			InvokerHelper.invokeStaticMethod(restScaffold, "findBy$capitalized", parameters)
		}else {
			InvokerHelper.invokeStaticMethod(restScaffold, method, parameters)
		}
	}
 
	protected format(obj) {
		withFormat{
			form { render obj as JSON }
			json { render obj as JSON }
			html { render (contentType:"text/plain",text: obj as JSON) }
		}
	}
}

윗부분에서 대충 사용방법을 설명했습니다만 혼란 스러울 것 같아서 순서대로 다시 설명합니다.

• 먼저 Domain 클래스를 다음과 같이 만듭니다.

package kr.grails
 
class Book {
	String name
 
	//final은 값을 변경해버리는 실수를 방지하기 위해서 넣은 것입니다. 
	static final restKey="name"
}

• Controller도 만들어 줍니다.

package kr.grails
 
class BookController extends RestController{
	//grails의 scaffold 모델과 최대한 비슷하게 만들려고 노력했습니다.
	def restScaffold = Book
 
	//이것은 UrlMappings의 샘플을 위해 만든 것입니다.
	def sample = {
		render "sample"
	}
}

/src/groovy/에 RestController.groovy도 넣어 줍니다.

• Config.groovy에서 json mime 타입도 설정 해줍니다.

grails.mime.types = [ ...
                      json: ['text/json'],
                      ...
                    ]

• UrlMappings.groovy도 설정합니다. 그리고 RestClient같은 걸로 테스트 해보면 잘 됩니다. RestClient도 groovy로 작성된 것 같습니다. swingbuilder로 말입니다.

class UrlMappings {
    static mappings = {
    	"/book/$restKey?"(controller:"book"){
    		action = [GET:"show", PUT:"create", POST:"update", DELETE:"delete"]
    	}
    	//이 라인이 있어야 /book/sample에 매핑됩니다. 순서가 restful action(/book/$restKey)보다 먼저 나오면 안됩니다.
    	"/book/$action"(controller:"book")
	}
}

1. Beginning Groovy And Grails